盒子论坛 v2.1

现在在给数据库的连接字符串加密，这样记录数据库名，用户名和用户密码就不会泄露给普通用户了（因为我加密之后就会是直接打开文件出现乱码），可是我不知道TWordTriple是什么数据类型，怎么定义，才能调用function TextEncrypt(const s: string; Key: TWordTriple): string; 等函数，请高手指教，做过这样工程的也请发表一下这样的做法，或是其他的方法思路。谢谢！

加密/解密代码如下：
unit EZCrypt;

{modeled by Ben Hochstrasser(bhoc@surfeu.ch) after some code snippet from borland}

interface

uses Windows, Classes;

type
  TWordTriple = Array[0..2] of Word;

function FileEncrypt(InFile, OutFile: String; Key: TWordTriple): boolean;
function FileDecrypt(InFile, OutFile: String; Key: TWordTriple): boolean;
function TextEncrypt(const s: string; Key: TWordTriple): string;
function TextDecrypt(const s: string; Key: TWordTriple): string;
function MemoryEncrypt(Src: Pointer; SrcSize: Cardinal; Target: Pointer; TargetSize: Cardinal; Key: TWordTriple): boolean;
function MemoryDecrypt(Src: Pointer; SrcSize: Cardinal; Target: Pointer; TargetSize: Cardinal; Key: TWordTriple): boolean;

implementation

function MemoryEncrypt(Src: Pointer; SrcSize: Cardinal; Target: Pointer; TargetSize: Cardinal; Key: TWordTriple): boolean;
var
  pIn, pOut: ^byte;
  i : Cardinal;
begin
  if SrcSize = TargetSize then
  begin
    pIn := Src;
    pOut := Target;
    for i := 1 to SrcSize do
    begin
      pOut^ := pIn^ xor (Key[2] shr 8);
      Key[2] := Byte(pIn^ + Key[2]) * Key[0] + Key[1];
      inc(pIn);
      inc(pOut);
    end;
    Result := True;
  end else
    Result := False;
end;

function MemoryDecrypt(Src: Pointer; SrcSize: Cardinal; Target: Pointer; TargetSize: Cardinal; Key: TWordTriple): boolean;
var
  pIn, pOut: ^byte;
  i : Cardinal;
begin
  if SrcSize = TargetSize then
  begin
    pIn := Src;
    pOut := Target;
    for i := 1 to SrcSize do
    begin
      pOut^ := pIn^ xor (Key[2] shr 8);
      Key[2] := byte(pOut^ + Key[2]) * Key[0] + Key[1];
      inc(pIn);
      inc(pOut);
    end;
    Result := True;
  end else
    Result := False;
end;

function TextCrypt(const s: string; Key: TWordTriple; Encrypt: Boolean): string;
var
  bOK: Boolean;
begin
  SetLength(Result, Length(s));
  if Encrypt then
    bOK := MemoryEncrypt(PChar(s), Length(s), PChar(Result), Length(Result), Key)
  else
    bOK := MemoryDecrypt(PChar(s), Length(s), PChar(Result), Length(Result), Key);
  if not bOK then Result := '';
end;

function FileCrypt(InFile, OutFile: String; Key: TWordTriple; Encrypt: Boolean): boolean;
var
  MIn, MOut: TMemoryStream;
begin
  MIn := TMemoryStream.Create;
  MOut := TMemoryStream.Create;
  Try
    MIn.LoadFromFile(InFile);
    MOut.SetSize(MIn.Size);
    if Encrypt then
      Result := MemoryEncrypt(MIn.Memory, MIn.Size, MOut.Memory, MOut.Size, Key)
    else
      Result := MemoryDecrypt(MIn.Memory, MIn.Size, MOut.Memory, MOut.Size, Key);
    MOut.SaveToFile(OutFile);
  finally
    MOut.Free;
    MIn.Free;
  end;
end;

function TextEncrypt(const s: string; Key: TWordTriple): string;
begin
  Result := TextCrypt(s, Key, True);
end;

function TextDecrypt(const s: string; Key: TWordTriple): string;
begin
  Result := TextCrypt(s, Key, False);
end;

function FileEncrypt(InFile, OutFile: String; Key: TWordTriple): boolean; begin
  Result := FileCrypt(InFile, OutFile, Key, True);
end;

function FileDecrypt(InFile, OutFile: String; Key: TWordTriple): boolean; begin
  Result := FileCrypt(InFile, OutFile, Key, False);
end;

字符串加密, 解密

----------------------------------------------
-

作者：

hongama (hongama)	★☆☆☆☆	-
	盒子活跃会员

2004/3/26 11:26:31

1楼：

高手快进啊，进来的同志帮我顶一下，谢谢！
我顶...........
----------------------------------------------
-

作者：

merry_bip (merry_bip)	★☆☆☆☆	-
	盒子活跃会员

2004/3/26 11:30:02

2楼：

这么简单的都不知道啊！！！
TWordTriple = Array[0..2] of Word; 他不是定义了吗！！

----------------------------------------------
merry_bip

作者：

hongama (hongama)	★☆☆☆☆	-
	盒子活跃会员

2004/3/26 11:32:39

3楼：

哈哈，我怎么这都没看，我去试试，我靠，一语惊醒梦中人啊
----------------------------------------------
-

作者：

hongama (hongama)	★☆☆☆☆	-
	盒子活跃会员

2004/3/26 11:33:56

4楼：

那又谁做过这样的程序的吗？给个经验之谈
----------------------------------------------
-

作者：

bios (阿贡)	★☆☆☆☆	-
	盒子中级会员

2004/3/26 11:40:14

5楼：

用tmemorystream 只能提示到这里自己动脑筋！

此帖子包含附件:

大小:101.4K

----------------------------------------------

作者：

hongama (hongama)	★☆☆☆☆	-
	盒子活跃会员

2004/3/26 11:46:19

6楼：

bios：不会吧，我考虑都很久了，要不，也不能连array都没看到啊，给个比较好的建议，行吗？
----------------------------------------------
-

信息

登陆以后才能回复