盒子论坛 v2.1

附件是整个测试工程，如果只是点击 TrayIcon 可以正常最小化和恢复。
但是如果在最小化的情况下点击 PopupMenu 来恢复窗体，就会出现BUG，窗体恢复不了。

其实代码也非常简单：
unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.AppEvnts, Vcl.Menus, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    TrayIcon1: TTrayIcon;
    PopupMenu1: TPopupMenu;
    ApplicationEvents1: TApplicationEvents;
    N1: TMenuItem;
    procedure ApplicationEvents1Minimize(Sender: TObject);
    procedure ApplicationEvents1Restore(Sender: TObject);
    procedure TrayIcon1Click(Sender: TObject);
    procedure N1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.ApplicationEvents1Minimize(Sender: TObject);
begin
  if Application.MainFormOnTaskBar then
    ShowWindow(Application.MainForm.Handle, SW_HIDE)
  else
    ShowWindow(Application.Handle, SW_HIDE);

  TrayIcon1.Visible := True;
end;

procedure TForm1.ApplicationEvents1Restore(Sender: TObject);
begin
  if Application.MainFormOnTaskBar then
    SetForegroundWindow(Application.MainForm.Handle)
  else
    SetForegroundWindow(Application.Handle);

  TrayIcon1.Visible := False;
end;

procedure TForm1.TrayIcon1Click(Sender: TObject);
begin
  if Self.WindowState = wsMinimized then
    Application.Restore
  else
    Application.Minimize;
end;

procedure TForm1.N1Click(Sender: TObject);
begin
  TrayIcon1Click(nil);
end;

end.

此帖子包含附件:nickemma_201912822226.rar 大小:4.9K

----------------------------------------------
-

作者：

bahamut8348 (leonna)	★☆☆☆☆	-
	普通会员

2019/12/9 13:55:06

1楼：

那么问题来了，为什么你要搞的这么复杂？发个消息不就完事儿了么？

procedure TForm1.TrayIcon1Click(Sender: TObject);
begin
  if not IsIconic(Self.Handle) then
    SendMessage(Self.Handle, WM_SYSCOMMAND, SC_MINIMIZE, 0)
  else
    SendMessage(Self.Handle, WM_SYSCOMMAND, SC_RESTORE, 0);
end;
----------------------------------------------
--

作者：

nickemma (N.E Zhou)	★☆☆☆☆	-
	普通会员

2019/12/9 20:16:04

2楼：

@bahamut8348
并不是我想这么复杂，在 Application.MainFormOnTaskBar := True 的情况下，用原生 TrayIcon，在最小化的时候除了托盘图标外，任务栏还保持的。所以才用ApplicationEvents事件，写代码去把任务栏取消，只保留托盘图标。

至于为什么打开 MainFormOnTaskBar ，请看官方解释：
MainFormOnTaskBar must be True to use Windows Vista or Windows 7 Aero effects, including live taskbar thumbnails, Dynamic Windows, Windows Flip, and Windows Flip 3D.

另外原生函数 Application.Minimize 和 Application.Restore 和你用SendMessage都是实现最小化和恢复而已，并不是我提出的BUG问题。不信你可以试试。
----------------------------------------------
-

作者：

kuei (kuei)	★☆☆☆☆	-
	盒子活跃会员

2019/12/10 8:06:45

3楼：

??? 不是有 CoolTrayIcon VCL吗？

此帖子包含附件:kuei_201912108642.zip 大小:709.3K

----------------------------------------------
-

作者：

hs_kill (lzl_17948876)	★☆☆☆☆	-
	普通会员

2019/12/10 9:07:36

4楼：

你这问题和popmenu没关系
就算没有菜单, 单纯的trayicon 加上你的代码一样会有问题
具体体现在, 你点击任务栏按钮最小化的时候, 会发现无论怎么调用application.restore都无法恢复, 因为此时代码里判断application.handle不是最小化状态
具体为什么我也不知道, VCL这层封装有点复杂

想解决其实也很简单, application.restore不能正确执行, 跟踪进去发现IsIconic(Handle)这句返回false, 也就是说在windows里记录的application窗口不是最小化状态, 自然也就不会被恢复了
所以, 你再调用application.restore之前吧application.handle强制设置为最小化的状态就可以了

procedure TForm1.TrayIcon1Click(Sender: TObject);
begin
  if Self.WindowState = wsMinimized then
  begin
    {这里加一句就可以了}
    SendMessage(Application.Handle, WM_SIZE, SIZE_MINIMIZED, 0);
    Application.Restore;
  end
  else
    Application.Minimize;
end;
----------------------------------------------
http://www.cnblogs.com/lzl_17948876/

作者：

bahamut8348 (leonna)	★☆☆☆☆	-
	普通会员

2019/12/10 16:22:26

5楼：

不知道楼主到底是要研究bug还是要达到目的，
如果要研究bug，这个bug自delphi6时代就存在，更早的没用过，不清楚。反正一直存在这个问题。问题也简单，就是在提供的几个minimize,restore等方法漏掉了改变窗口状态的代码。
解决办法就是发一个还原窗口的消息给application.handle，或者干脆就直接用win32消息来控制窗口的最大化和最小化。比如我贴的代码。
如果你一定要死磕这个bug，可以去cg提交一个bug，如果要快速解决问题完成项目收钱就赶快找其他解决方案。而不是一直纠正我的错误。
----------------------------------------------
--

作者：

nickemma (N.E Zhou)	★☆☆☆☆	-
	普通会员

2019/12/10 22:35:42

6楼：

@bahamut8348
哦，原来这个真的是BUG，而且由来已久，我真的不知道。

并不是我死磕这个BUG，而是这段时间在写一个小应用的时候发现的，开始一直以为是自己代码出现问题，检查后发现并不是，才写了个DEMO发上论坛。

我初衷是可以用原生的函数就用原生的，培养好这个习惯日后如果需要跨平台，比如LINUX，这样也就不需要修改代码。但最终也是跟你一样妥协用SendMessage来解决问题。

另外吐槽一下EMB公司，也真是奇葩，这么一个BUG，竟然横跨了多少个版本？
----------------------------------------------
-

作者：

bahamut8348 (leonna)	★☆☆☆☆	-
	普通会员

2019/12/10 22:41:04

7楼：

linux上ui并不是那么简单的，linux的xwindow版本本身就多，要兼容不是个容易的事情，而且linux基本都是数据中心，有shell就足够了。
----------------------------------------------
--

作者：

vkow (vkow)	★☆☆☆☆	-
	普通会员

2019/12/11 7:44:35

8楼：

还真不知道这bug。

其实，bug这玩意靠运气。好多人习惯于自己的写法，恰巧绕过了bug。
----------------------------------------------
-

信息

登陆以后才能回复