盒子论坛 v2.1

unit UntObject;

interface

uses
  DB, Classes;

var
  CXlsBof: array[0..5] of Word = ($809, 8, 0, $10, 0, 0);
  CXlsEof: array[0..1] of Word = ($0A, 00);
  CXlsLabel: array[0..5] of Word = ($204, 0, 0, 0, 0, 0);
  CXlsNumber: array[0..4] of Word = ($203, 14, 0, 0, 0);
  CXlsRk: array[0..4] of Word = ($27E, 10, 0, 0, 0);
  CXlsBlank: array[0..4] of Word = ($201, 6, 0, 0, $17);

Type
  TDS2Excel = Class(TObject)
  Private
    FCol: word;
    FRow: word;
    FDataSet: TDataSet;
    Stream: TStream;
    FWillWriteHead: boolean;
    FBookMark: TBookmark;
    procedure IncColRow;
    procedure WriteBlankCell;
    procedure WriteFloatCell(const AValue: Double);
    procedure WriteIntegerCell(const AValue: Integer);
    procedure WriteStringCell(const AValue: string);
    procedure WritePrefix;
    procedure WriteSuffix;
    procedure WriteTitle;
    procedure WriteDataCell;

    procedure Save2Stream(aStream: TStream);
  Public
    procedure Save2File(FileName: string; WillWriteHead: Boolean);
    Constructor Create(aDataSet: TDataSet);
  end;

implementation

uses
  SysUtils;

Constructor TDS2Excel.Create(aDataSet: TDataSet);
begin
  inherited Create;
  FDataSet := aDataSet;
end;

procedure TDS2Excel.IncColRow;
begin
  if FCol = FDataSet.FieldCount - 1 then
  begin
    Inc(FRow);
    FCol :=0;
  end
  else
    Inc(FCol);
end;

procedure TDS2Excel.WriteBlankCell;     //写空单元
begin
  CXlsBlank[2] := FRow;
  CXlsBlank[3] := FCol;
  Stream.WriteBuffer(CXlsBlank, SizeOf(CXlsBlank));
  IncColRow;
end;

procedure TDS2Excel.WriteFloatCell(const AValue: Double);  //写浮点单元
begin
  CXlsNumber[2] := FRow;
  CXlsNumber[3] := FCol;
  Stream.WriteBuffer(CXlsNumber, SizeOf(CXlsNumber));
  Stream.WriteBuffer(AValue, 8);
  IncColRow;
end;

procedure TDS2Excel.WriteIntegerCell(const AValue: Integer);   //写整数单元
var
  V: Integer;
begin
  CXlsRk[2] := FRow;
  CXlsRk[3] := FCol;
  Stream.WriteBuffer(CXlsRk, SizeOf(CXlsRk));
  V := (AValue shl 2) or 2;
  Stream.WriteBuffer(V, 4);
  IncColRow;
end;

procedure TDS2Excel.WriteStringCell(const AValue: string);   //写字符单元
var
  L: Word;
begin
  L := Length(AValue);
  CXlsLabel[1] := 8 + L;
  CXlsLabel[2] := FRow;
  CXlsLabel[3] := FCol;
  CXlsLabel[5] := L;
  Stream.WriteBuffer(CXlsLabel, SizeOf(CXlsLabel));
  Stream.WriteBuffer(Pointer(AValue)^, L);
  IncColRow;
end;

procedure TDS2Excel.WritePrefix;   //写前缀
begin
  Stream.WriteBuffer(CXlsBof, SizeOf(CXlsBof));
end;

procedure TDS2Excel.WriteSuffix;   //写后缀
begin
  Stream.WriteBuffer(CXlsEof, SizeOf(CXlsEof));
end;

procedure TDS2Excel.WriteTitle; 　//写标题
var
  n: word;
begin
  for n := 0 to FDataSet.FieldCount - 1 do
    WriteStringCell(FDataSet.Fields[n].FieldName);
end;

procedure TDS2Excel.WriteDataCell;   //正式写入Excel表的数据
var
  n: word;
begin
  WritePrefix;   //写前缀

  if FWillWriteHead then
    WriteTitle;

  FDataSet.DisableControls;

  FBookMark := FDataSet.GetBookmark;
  FDataSet.First;
  while not FDataSet.Eof do
  begin
    for n := 0 to FDataSet.FieldCount - 1 do
    begin
      if FDataSet.Fields[n].IsNull then
        WriteBlankCell  //如果n字段为空，则写空单元
      else
      begin
        case FDataSet.Fields[n].DataType of
          ftSmallint, ftInteger, ftWord, ftAutoInc, ftBytes : WriteIntegerCell(FDataSet.Fields[n].AsInteger);
          ftFloat, ftCurrency, ftBCD          : WriteFloatCell(FDataSet.Fields[n].AsFloat);
        else
          WriteStringCell(FDataSet.Fields[n].AsString);
        end;
      end;
    end;
    FDataSet.Next;
  end;

  WriteSuffix; //写后缀

  if FDataSet.BookmarkValid(FBookMark) then
    FDataSet.GotoBookmark(FBookMark);

  FDataSet.EnableControls;
end;

procedure TDS2Excel.Save2Stream(aStream: TStream);   //按流保存
begin
  FCol := 0;
  FRow := 0;
  Stream := aStream;
  WriteDataCell;
end;

procedure TDS2Excel.Save2File(FileName: string; WillWriteHead: Boolean);  //保存到文件
var
  aFileStream: TFileStream;
begin
  FWillWriteHead := WillWriteHead;

  if FileExists(FileName) then
    DeleteFile(FileName);

  aFileStream := TFileStream.Create(FileName, fmCreate);
  Try
    Save2Stream(aFileStream);
  Finally
    aFileStream.Free;
  end;
end;

end.
----------------------------------------------
-

信息

登陆以后才能回复